A ntfy-alertmanager-git/PKGBUILD => ntfy-alertmanager-git/PKGBUILD +53 -0
@@ 0,0 1,53 @@
+# Maintainer: Thorben Günther <echo YWRtaW5AeGVucm94Lm5ldAo= | base64 -d>
+
+pkgname=ntfy-alertmanager-git
+_pkgname=ntfy-alertmanager
+pkgver=v0.1.0.r0.g5109867
+pkgrel=1
+pkgdesc='ntfy alertmanager bridge'
+arch=('x86_64')
+url='https://git.xenrox.net/~xenrox/ntfy-alertmanager'
+license=('AGPL3')
+makedepends=('git' 'go' )
+provides=('ntfy-alertmanager')
+conflicts=('ntfy-alertmanager')
+source=(
+ "$_pkgname::git+https://git.xenrox.net/~xenrox/${_pkgname}"
+ "ntfy-alertmanager.service"
+ "sysusers.conf"
+)
+sha256sums=('SKIP'
+ '39f776c506f476de716737407f85c2c53b8a57f5273d71660122ebee7426890c'
+ '7d9183eac94bedc9c82b4abcb6b50b262599f079d2d078cdafe5bb6019464da4')
+
+pkgver() {
+ cd "$srcdir/$_pkgname"
+ (
+ set -o pipefail
+ git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+ printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+ )
+}
+
+check() {
+ cd "$srcdir/$_pkgname"
+ go test ./...
+}
+
+build() {
+ cd "$srcdir/$_pkgname"
+ export CGO_LDFLAGS="${LDFLAGS}"
+ export CGO_CFLAGS="${CFLAGS}"
+ export CGO_CPPFLAGS="${CPPFLAGS}"
+ export CGO_CXXFLAGS="${CXXFLAGS}"
+ export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+
+ go build -o ntfy-alertmanager
+}
+
+package() {
+ cd "$srcdir/$_pkgname"
+ install -Dm755 ntfy-alertmanager "$pkgdir"/usr/bin/ntfy-alertmanager
+ install -Dm644 ../ntfy-alertmanager.service -t "$pkgdir"/usr/lib/systemd/system/
+ install -Dm644 ../sysusers.conf "$pkgdir"/usr/lib/sysusers.d/ntfy-alertmanager.conf
+}
A ntfy-alertmanager-git/ntfy-alertmanager.service => ntfy-alertmanager-git/ntfy-alertmanager.service +13 -0
@@ 0,0 1,13 @@
+[Unit]
+Description=ntfy-alertmanager service
+Requires=network-online.target
+After=network-online.target
+
+[Service]
+Type=simple
+User=ntfy-alertmanager
+Restart=always
+ExecStart=/usr/bin/ntfy-alertmanager
+
+[Install]
+WantedBy=multi-user.target
A ntfy-alertmanager-git/sysusers.conf => ntfy-alertmanager-git/sysusers.conf +1 -0
@@ 0,0 1,1 @@
+u ntfy-alertmanager - "ntfy-alertmanager user"