~xenrox/personal-packages

0502a43e18463612c34a579d354dd8d802e2061a — Thorben Günther 6 months ago 06be30a
Add syncthing-status
1 files changed, 30 insertions(+), 0 deletions(-)

A syncthing-status/PKGBUILD
A syncthing-status/PKGBUILD => syncthing-status/PKGBUILD +30 -0
@@ 0,0 1,30 @@
# Maintainer: Thorben Günther <echo YWRtaW5AeGVucm94Lm5ldAo= | base64 -d>

pkgname=syncthing-status
pkgver=0.1.0
pkgrel=1
pkgdesc='Simple syncthing status'
arch=('x86_64')
url='https://git.xenrox.net/~xenrox/syncthing-status'
license=('MIT')
makedepends=('go')
source=(
    "$pkgname-$pkgver.tar.gz::https://git.xenrox.net/~xenrox/${pkgname}/archive/${pkgver}.tar.gz"
)
sha256sums=('388571d78cf66d572ac037f961a9cf7cea1d5c51924fd8f4963c34d9bf1d78e1')

build() {
    cd "$srcdir/$pkgname-$pkgver"
    export CGO_LDFLAGS="${LDFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"

    go build -o syncthing-status
}

package() {
    cd "$srcdir/$pkgname-$pkgver"
    install -Dm755 syncthing-status "$pkgdir"/usr/bin/syncthing-status
}